* GrADS Script to compute mean and standard deviation 
* for precipitation data per month in HW #3

* Open GrADS control file

'open precipmonthly_usmx_le.ctl'


* Set script to write out files in binary format 

'set gxout fwrite'


* Define years at 2-D field

'define totalyears=55'

* Initialize summation arrays (for each month)

mo=1
monthsyr=12
totalmonths=660

'define years=55'

while(mo<monthsyr+1)

  'define sumprecip'mo'=0'
  'define sumprecipsq'mo'=0'
  mo=mo+1

endwhile


* Compute the sum and sumsq of precipitation per month
* NOTE:  No need for loops in space here!

tt=1

while(tt<totalmonths+1)
  mo=1

  while(mo<monthsyr+1)
    'set t 'tt  
    'define sumprecip'mo'=sumprecip'mo'+p'
    'define sumprecipsq'mo'=sumprecipsq'mo'+p*p'
    tt=tt+1
    mo=mo+1
  endwhile

endwhile


* Compute mean and std. deviation of precipitation 

mo=1

while(mo<monthsyr+1)

  'define meanprecip'mo'=sumprecip'mo'/totalyears'
  'define stdevprecip'mo'=sqrt((totalyears*sumprecipsq'mo'-sumprecip'mo'*sumprecip'mo')/(totalyears*(totalyears-1)))'
  mo=mo+1

endwhile

* Write out data to file (called grads.fwrite), using d command

mo=1

while(mo<monthsyr+1)

  'd meanprecip'mo
  'd stdevprecip'mo
  mo=mo+1

endwhile

* Move the grads.fwrite file (must use ! since it's a unix command
* within grads)

'!mv grads.fwrite monthly_stats_grads.bin'

*